payfrit-biz/api/assignments/save.cfm

<cfsetting showdebugoutput="false">
<cfsetting enablecfoutputonly="true">

<cfcontent type="application/json; charset=utf-8" reset="true">
<cfheader name="Cache-Control" value="no-store">

<cfscript>
function apiAbort(obj){
  writeOutput(serializeJSON(obj));
  abort;
}

function readJsonBody(){
  raw = toString(getHttpRequestData().content);
  if (isNull(raw) || len(trim(raw)) EQ 0){
    apiAbort({OK=false,ERROR="missing_body"});
  }
  try {
    parsed = deserializeJSON(raw);
  } catch(any e){
    apiAbort({OK=false,ERROR="bad_json",MESSAGE="Invalid JSON body"});
  }
  if (!isStruct(parsed)){
    apiAbort({OK=false,ERROR="bad_json",MESSAGE="JSON must be an object"});
  }
  return parsed;
}

/* ---------- AUTH CONTEXT ---------- */
if (!structKeyExists(request,"BusinessID") || !isNumeric(request.BusinessID) || request.BusinessID LTE 0){
  apiAbort({OK=false,ERROR="no_business_selected"});
}

/* ---------- INPUT ---------- */
data = readJsonBody();

if (!structKeyExists(data,"BeaconID") || !isNumeric(data.BeaconID) || int(data.BeaconID) LTE 0){
  apiAbort({OK=false,ERROR="missing_BeaconID"});
}
if (!structKeyExists(data,"ServicePointID") || !isNumeric(data.ServicePointID) || int(data.ServicePointID) LTE 0){
  apiAbort({OK=false,ERROR="missing_ServicePointID"});
}

BeaconID = int(data.BeaconID);
ServicePointID = int(data.ServicePointID);
</cfscript>

<!--- Validate Beacon is allowed for this Business:
      Owner (Beacons.BusinessID) OR join table (lt_BeaconsID_BusinessesID) OR parent's owner --->
<cfquery name="qBiz" datasource="payfrit">
  SELECT ID, ParentBusinessID
  FROM Businesses
  WHERE ID = <cfqueryparam cfsqltype="cf_sql_integer" value="#request.BusinessID#">
  LIMIT 1
</cfquery>

<cfquery name="qB" datasource="payfrit">
  SELECT b.ID
  FROM Beacons b
  WHERE b.ID = <cfqueryparam cfsqltype="cf_sql_integer" value="#BeaconID#">
    AND (
      b.BusinessID = <cfqueryparam cfsqltype="cf_sql_integer" value="#request.BusinessID#">
      <cfif qBiz.recordCount GT 0 AND len(trim(qBiz.ParentBusinessID)) GT 0 AND isNumeric(qBiz.ParentBusinessID) AND qBiz.ParentBusinessID GT 0>
        OR b.BusinessID = <cfqueryparam cfsqltype="cf_sql_integer" value="#qBiz.ParentBusinessID#">
      </cfif>
      OR EXISTS (
        SELECT 1 FROM lt_BeaconsID_BusinessesID lt
        WHERE lt.BeaconID = b.ID
          AND lt.BusinessID = <cfqueryparam cfsqltype="cf_sql_integer" value="#request.BusinessID#">
      )
    )
  LIMIT 1
</cfquery>
<cfif qB.recordCount EQ 0>
  <cfoutput>#serializeJSON({OK=false,ERROR="beacon_not_allowed"})#</cfoutput>
  <cfabort>
</cfif>

<!--- Validate ServicePoint belongs to Business --->
<cfquery name="qS" datasource="payfrit">
  SELECT ID
  FROM ServicePoints
  WHERE ID = <cfqueryparam cfsqltype="cf_sql_integer" value="#ServicePointID#">
    AND BusinessID = <cfqueryparam cfsqltype="cf_sql_integer" value="#request.BusinessID#">
  LIMIT 1
</cfquery>
<cfif qS.recordCount EQ 0>
  <cfoutput>#serializeJSON({OK=false,ERROR="servicepoint_not_found_for_business"})#</cfoutput>
  <cfabort>
</cfif>

<!--- Check if this ServicePoint already has this beacon assigned --->
<cfquery name="qDuplicate" datasource="payfrit">
  SELECT ID
  FROM ServicePoints
  WHERE ID = <cfqueryparam cfsqltype="cf_sql_integer" value="#ServicePointID#">
    AND BeaconID = <cfqueryparam cfsqltype="cf_sql_integer" value="#BeaconID#">
  LIMIT 1
</cfquery>
<cfif qDuplicate.recordCount GT 0>
  <cfoutput>#serializeJSON({OK=false,ERROR="assignment_already_exists"})#</cfoutput>
  <cfabort>
</cfif>

<!--- Assign beacon to service point --->
<cfquery datasource="payfrit">
  UPDATE ServicePoints
  SET BeaconID = <cfqueryparam cfsqltype="cf_sql_integer" value="#BeaconID#">,
      AssignedByUserID = <cfqueryparam cfsqltype="cf_sql_integer" value="1">
  WHERE ID = <cfqueryparam cfsqltype="cf_sql_integer" value="#ServicePointID#">
    AND BusinessID = <cfqueryparam cfsqltype="cf_sql_integer" value="#request.BusinessID#">
</cfquery>

<cfoutput>#serializeJSON({
  "OK"=true,
  "ACTION"="assigned",
  "ServicePointID"=ServicePointID,
  "BeaconID"=BeaconID,
  "BusinessID"=(request.BusinessID & "")
})#</cfoutput>